!
! Spacer Quest Include File
!


getit
 ? "[ Press any key to continue ]";:get mode(1) i$
 print repeat$(" ",29);:return

crfix
 if g2<0 g2=8000000                   ! 8 million is the limit...anything above
 if g2>8000000 g2=8000000             ! that, and you're into negative #'s!
cfix
 g$=str$(g2)
 return

run.term
 run"1/main","term0"

stfx
 l=len(lm$):l=15-l
 lm$==+repeat$("_",l)
 l=len(l$):l=27-l
 l$==+repeat$("_",l)
 ln$=right$("   "+str$(j),5)
 print" "lm$l$"[:"ln$":]___[:"k":]"
 return

varfix
 if f1<1 f1=0
 f2=0:k1==+q1:if (k1>29999) k1=0
 j1==+q6:if (j1>29999) j1=0
 u1==+1:e1==+wb:m1==+lb
 s2=(s2+wb+q6+y)-lb:wb=0:lb=0
 if s2<1 s2=0
 y=0
 return

shipw
! if ee<1 return
 if oo>np create "21/sq.num",4:open #1,"21/sq.num":print #1,oo:np=oo:close #1
 open #1,"21/spacers1":position #1,256,oo
 print #1,na$\nz$\h1$\d1$\c1$\l1$\w1$\n1$\r1$\p$(1)\t$\q2$\q4$\sp$\pp$\ap$
 close
 open #1,"21/spacers2":position #1,256,oo 
 print #1,h1,d1,c1,l1,w1,n1,r1,p1,g1,f1
 print #1,h2,d2,c2,l2,w2,n2,r2,p2,g2,f2
 print #1,s1,j1,k1,m1,sc,e1,u1,b1,sp,pp
 print #1,s2,q1,q2,q3,q4,q5,o1,z1,t1,ap,q6
 close:return

rand1
 x=(random(xr)+1)*10
 x=random(r):if x>r x=r
 if x<1 x=1
 return

rand2
 x=random(r)+1
 if x>r x=r
 if x<1 x=1
 return

galaxy
 if i=1 ll$="Sun-3"
 if i=2 ll$="Aldebaran-1"
 if i=3 ll$="Altair-3"
 if i=4 ll$="Arcturus-6"
 if i=5 ll$="Deneb-4"
 if i=6 ll$="Denebola-5"
 if i=7 ll$="Fomalhaut-2"
 if i=8 ll$="Mira-9"
 if i=9 ll$="Pollux-7"
 if i=10 ll$="Procyon-5"
 if i=11 ll$="Regulus-6"
 if i=12 ll$="Rigel-8"
 if i=13 ll$="Spica-3"
 if i=14 ll$="Vega-6"
 return

allname
 if i=1 ll$="Astro League":return
 if i=2 ll$="Space Dragons":return
 if i=3 ll$="Warlord Confed":return
 if i=4 ll$="Rebel Alliance":return
 return

shipstat
 if h1>19 hx=19:goto sss
 if h1>9 hx=(h1-10):else hx=h1

sss
 ic$="21/spic."+str$(hx)
 tcopy ic$
 print"Ship's Name...: "nz$
 print" Section        Type"repeat$(" ",23)"Cond    Strength"
 print" -------        ----"repeat$(" ",23)"-----   --------"
 ll$=h1$:gosub statfix
 print" Hull___________"ll$"[ "h2" ]______"h1
 ll$=d1$:gosub statfix
 print" Drive__________"ll$"[ "d2" ]______"d1
 ll$=c1$:gosub statfix
 print" Cabin__________"ll$"[ "c2" ]______"c1
 ll$=l1$:gosub statfix
 print" Life Support___"ll$"[ "l2" ]______"l1
 ll$=w1$:gosub statfix
 print" Weapons________"ll$"[ "w2" ]______"w1
 ll$=n1$:gosub statfix
 print" Navigation_____"ll$"[ "n2" ]______"n1
 ll$=r1$:gosub statfix
 print" Robotics_______"ll$"[ "r2" ]______"r1
 ll$=p$(1):gosub statfix
 print" Shields________"ll$"[ "p2" ]______"p1
 print" Fuel Units"repeat$("_",32)"[ "h2" ]______"f1
 print" Cargo Pods"repeat$("_",32)"[ "h2" ]______"s1;
 if q1>0 print" "q2$:else print" Empty"
 return

statfix
 lw=len(ll$):lw=27-lw:ll$==+repeat$("_",lw)
 return

fcost
 f2=0
 if x<1 return
 af=d1:if af>21 af=21
 f2=(21-af)+(10-d2)
 if f2<1 f2=1
 f2==*x:ty=f2+10
 if ty>100 ty=100
 f2=ty/2
 return

sqfix1f                 ! from fight
 gosub spfix1x(22):return
spfix1
 gosub spfix1x(20):return
spfix1x
 lw=len(lm$):lw=(&1-lw):if lw<0 lw=0
 lm$==+repeat$(" ",lw)
 return
sqfix2f                 ! from fight
 gosub spfix2x(22):return
spfix2
 gosub spfix2x(12):return
spfix2x
 lw=len(ln$):lw=(&1-lw):if lw<0 lw=0
 ln$==+repeat$(" ",lw)
 return

legend
 ?"
 _____________________________________________________________________________
|                                                                             |
| ( 1)...Sun-3         ( 5)...Deneb-4       ( 9)...Pollux-7    (13)...Spica-3 |
| ( 2)...Aldebaran-1   ( 6)...Denebola-5    (10)...Procyon-5   (14)...Vega-6  |
| ( 3)...Altair-3      ( 7)...Fomalhaut-2   (11)...Regulus-6                  |
| ( 4)...Arcturus-6    ( 8)...Mira-9        (12)...Rigel-8                    |
|_____________________________________________________________________________|
 "
 return

legend2
 ?"
 _____________________________________________________________________________
|                                                                             |
| ( 1)...Sun-3        ( 6)...Denebola-5   (11)...Regulus-6  (16)...Capella-4  |
| ( 2)...Aldebaran-1  ( 7)...Fomalhaut-2  (12)...Rigel-8    (17)...Polaris-1  |
| ( 3)...Altair-3     ( 8)...Mira-9       (13)...Spica-3    (18)...Mizar-9    |
| ( 4)...Arcturus-6   ( 9)...Pollux-7     (14)...Vega-6     (19)...Achernar-5 |
| ( 5)...Deneb-4      (10)...Procyon-5    (15).*.Antares-5  (20)...Algol-2    |
|_____________________________________________________________________________|
 "
 return

map
 ?"

                  Spatial Map of Civilized Star Systems
                  -------------------------------------

 -*-10

            -*-7                                                -*-13

                           -*-5
                                 -*-6
            -*-2
                                                    -*-11
                  -***-[1]
                                                                -*-12
                             -*-4
            -*-3
                                           -*-9 
 -*-8
                                                                        -*-14
-------------------------------------------------------------------------------
"
 return


SystemCrash
 clear for                      ! Make sure we don't crash in the crash sub!
 clear if
 clear return
 if syserr=254 end              ! Don't trap those damn OA-Control-C commands
 ? cr cr"**** A "syserr$" error has occured : one moment, please...";
 close
 long if ssi(22)
    f$="7/crash.log":create f$,4:open #1,f$:append #1
    ? #1,"Crash number "errs" for caller number "stat(3,0)"/"stat(3,1) cr
    ? #1,"Time of error : "date$" "time$
    ? #1,"  User online : "usr$(0)" (#"user")"
    ? #1,"  Module name : "sysinfo$(4)
    ? #1,"Error message : "syserr$
    ? #1,repeat$("-",79):close #1
 end if
 print
 errs==+1:gosub ProdosError
 if (errs<5) or staff goto CrashRecover
 ? "
   Sorry, an excessive amount of System Errors have been detected within the
Future Vision program.  In order to retain the integrity of the BBS, the system
will be rebooted, and you will be disconnected. Thank you for your cooperation.
":run "1/startup","clear"

ProdosError
 if not doserr ? ".Done"cr:else ? ".ProDOS Error #"doserr cr
 return

CrashRecover
 gosub SetTraps:run "1/main","GameRoomEnter"