Path: news1.icaen!news.uiowa.edu!uunet!in3.uu.net!206.229.87.25!news-peer.sprintlink.net!sprint!news-dc-26.sprintlink.net!news.sprintlink.net!news-pen-15.sprintlink.net!news.sover.net!news.monad.net!blues.jpj.net!scalar
From: scalar@blues.jpj.net (Scalar)
Newsgroups: comp.sys.apple2.programmer
Subject: Re: Do you have any BASIC Programmes?
Date: 11 Apr 1997 23:47:25 GMT
Organization: MonadNet
Lines: 47
Message-ID: <5imiid$n89@news.monad.net>
References: <williams.inver-0504971919540001@dial1port4.sol.co.uk>
NNTP-Posting-Host: blues.jpj.net
X-Newsreader: TIN [version 1.2 PL2]

Philip Williams (williams.inver@sol.co.uk) scribbled out the following:
: Does anyone have any programmes that they can e-mail me with?

Here's my random geometric object program, from memory.
Since I don't have an emulator handy, I can't test this right
now, and so this may not be totally bug-free. Mail me if there
are any problems..

 10 text : home : normal
 20 print tab(8)"Random Geometric Objects"
 30 print tab(9)"(c) 1997  Dale Mahalko"
 40 print tab(10)"Email: scalar@jpj.net": vtab 7
 50 print "While running, press any key to draw a"
 60 print "new shape, or press <Escape> to exit."
 70 print : print "Press any key to continue..";
 80 GET ky$ : print : home
 88 REM
 89 REM >>>Create array to store shape of object..
 90 cn% = 30 : dim sc%(cn%),rt%(cn%) 
108 REM
109 REM >>>Create a simple shapetable..
110 poke 232,0 : poke 233,3: for a% = 1 to 6
120 poke 767+a%,val(mid$("104040",a%,1)) : next a%
128 REM
129 REM >>>Initialize hires graphics page 0..
130 hgr : poke -16302,0 : scale = 1 : rot = 0 : xdraw 1 at 139,95
138 REM 
139 REM >>>Store shape of object to draw in arrays sc% and rt%..
140 max% = rnd(1)*(cn%-3)+3 : r% = 0: for a% = 1 to max%
150 sc%(a%)=rnd(1)*80+1 : rt%(a%)=rnd(1)*63 : next a%
158 REM
159 REM >>>Loop to draw shapes.
160 for a% = 1 to max% : scale = sc%(a%) : r%=r% + rt%(a%)
170 r%=r%-64*(r%>63)+64*(r%<0) : rot = r%: xdraw 1 : next a%
180 if peek(-16368)-128 = 27 then text : poke -16384,0 : end
190 if peek(-16368)<128 then 160
200 goto 130

-Scalar

--
Notice to Advertisers: You do not have permission to send me your
advertisements. My mere posting on Usenet does not give you the
permission to mail me your unwanted crap. This is your only notice.
NO SOLICITING. NO JUNK MAIL. NO E-MAIL SPAM.