FUZZY LOGIC APPLICATION
                   FUZZY VEHICLE UNDERWRITING MODEL
                             BY EARL COX

    NOTE:   YOU CAN RUN A VERSION OF THIS EXAMPLE WITH FIDE DEMO

$--Fuzzy Vehicle Underwriting Model
$--Au: Earl Cox, Metus Systems, (c) 1992 (914) 238-0647
$--Notes: This is a simplified version of the vehicle underwiting model
$----based on age, driving experience, closness to city center,
$----accidents, and number of moving violations in the past 12 months.
$----The model either increases or decreases the consequent risk state
$----based on the severity of these factors.  We are exploring the
$----implication space only.  No reasonable value and integrity checks
$----have been implemented (eg. a 16 year old with 5 years of driving
$----experience.)
$--License: This Fide model is distributed to Aptronix for the
$----exclusive use of their staff and their clients. This model
$----is expressly released without warranty of fitness for any
$----particular application or use. This means you're on your own!
$
$--NOTE: To run this under Fide Demo, remove the accidents and 
$----violations "invar" and rule statements (These are the last
$----two variable and rule entries)
$		
$
fiu tvfi (prod sum) *8;
$  *-----------------------------------------------------------------------*
$  * INPUT VARIABLES. These are the control variables that determine the   |
$  * the degree of risk in writing this vehicle policy.                    |
$  *-----------------------------------------------------------------------*
invar age            " ": 16 () 80  
   [high_risk_for_age           "agehi.fzs",
   not_high_risk_for_age        "agenhi.fzs",
   middle_aged            (@16,0,@40,1,@80,0)  ];
invar experience     " ":  0 () 72  	
   [lo_for_experience      "explo.fzs",
   not_lo_for_experience   "expnlo.fzs"       ];
invar dist_from_city " ":  0 () 100 
   [close_to_city          "citycl.fzs",
   not_close_to_city       "cityncl.fzs"      ];
invar violations     " ":  0 () 5
   [high_for_violations    (@0,0,@5,1)        ];
invar accidents      " ":  0 () 8
   [high_for_accidents     (@0,0,@8,1)        ];
$  *-----------------------------------------------------------------------*
$  *  SOLUTION VARIABLE. Risk is a calibrated metric whose height is based |
$  *  on the truth of the rule evaluation. We find the center of gravity   |
$  *  of the consequent risk space to determine the expected value.        |
$  *-----------------------------------------------------------------------*
outvar risk  " ": 0 () 250 * (
   none=0,
   low=40,
   acceptable=100,
   high=160,
   considerable=200,
   extreme=240);
   
$  *-----------------------------------------------------------------------*
$  *  RULES. This is the underwriter's knowledge about how a policy risk   |
$  *  is determined. The quantitative assessment of risk is increased or   |
$  *  decreased based on such factors as age, driving experience, general  |
$  *  moving violation and accident history, etc.                          |
$  *-----------------------------------------------------------------------*
$--Consider Age as the principal determining factor. Young drivers
$----(between 16 and 25) and very old drivers (over 68) have higher
$----degrees of risk. This is reflected in the age membership function.

if age is high_risk_for_age                      then risk is high;
if age is not_high_risk_for_age                  then risk is low;
if age is high_risk_for_age 
     and experience is lo_for_experience         then risk is considerable;